Come posso usare le variabili Shell in uno script awk?

Ottenere le variabili Shell in awk

può essere fatto in diversi modi. Alcuni sono migliori di altri. Questo dovrebbe riguardare la maggior parte di loro. Se hai un commento, per favore, lascia qui sotto.

- Using -v (Il modo migliore, più portatile)

Usa l'opzione -v: (P.S. usa uno spazio dopo -v o sarà meno portabile.E., awk -v var= not awk -vvar=)

variable="line one\nline two"
awk -v var="$variable" 'BEGIN {print var}'
line one
line two

Questo dovrebbe essere compatibile con la maggior parte di awk e la variabile è disponibile anche nel blocco BEGIN:

Se hai più variabili:

awk -v a="$var1" -v b="$var2" 'BEGIN {print a,b}'

Avvertimento. Come scrive Ed Morton, le sequenze di escape verranno interpretate in modo che \t diventi un tab reale e non \t se questo è ciò che si cerca. Può essere risolto utilizzando ENVIRON[] o accedendolo tramite ARGV[]

- Variabile dopo il blocco del codice

Qui otteniamo la variabile dopo il codice awk. Funzionerà bene finché non avrai bisogno della variabile nel blocco BEGIN:

variable="line one\nline two"
echo "input data" | awk '{print var}' var="${variable}"
or
awk '{print var}' var="${variable}" file

Funziona anche con più variabili awk '{print a,b,$0}' a="$var1" b="$var2" file

L'uso della variabile in questo modo non funziona nel blocco BEGIN:

echo "input data" | awk 'BEGIN {print var}' var="${variable}"

- Here string

La variabile può anche essere aggiunta a awk usando here string

awk '{print $0}' <<< "$variable"
test

Questo è lo stesso di:

echo "$variable" | awk '{print $0}'

PS, questo minaccia la variabile come input di file

- ENVIRON input

Come TrueY write, puoi usare ENVIRON per stampare Environmental Variables Impostando una variabile prima di eseguire AWK, puoi stamparla in questo modo:

X=MyVar awk 'BEGIN{print ENVIRON["X"],ENVIRON["Shell"]}'
MyVar /bin/bash

- Ingresso ARGV

Come scrive Steven Penny, puoi usare ARGV per fare in modo che la raccolta di dati funzioni.

v="my data"
awk 'BEGIN {print ARGV[1]}' "$v"
my data

Per ottenere il data inn per il codice stesso non solo l'INIZIO:

v="my data"
echo "test" | awk 'BEGIN{var=ARGV[1];ARGV[1]=""} {print var, $0}' "$v"
my data test

- Variabile all'interno del codice: USE WITH CAUTION

Puoi usare una variabile all'interno del codice awk, ma è disordinata e difficile da leggere e, come sottolinea Charles Duffy, questa versione potrebbe anche essere vittima dell'iniezione di codice. Se qualcuno aggiunge cose cattive alla variabile, verrà eseguito come parte del codice awk.

Funziona estraendo la variabile all'interno del codice, quindi diventa parte di esso.

Se vuoi creare un awk che cambia dinamicamente con l'uso di variabili, puoi farlo in questo modo, bot NON usarlo per le variabili normali.

variable="line one\nline two"
awk 'BEGIN {print "'"$variable"'"}'
line one
line two

Ecco un esempio di iniezione di codice:

variable='line one\nline two" ; for (i=1;i<=1000;++i) print i"'
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
1
2
3
.
.
1000

È possibile aggiungere molti comandi a awk in questo modo. Anche farlo schiantare con comandi non validi.

- Ulteriori informazioni:

Uso della doppia citazione
È sempre bene raddoppiare la variabile "$variable"
In caso contrario, verranno aggiunte più righe come una lunga linea singola.

Esempio:

var="Line one
This is line two"

echo $var
Line one This is line two

echo "$var"
Line one
This is line two

Altri errori che puoi ottenere senza virgolette doppie:

variable="line one\nline two"
awk -v var=$variable 'BEGIN {print var}'
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ backslash not last character on line
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ syntax error

E con virgolette singole, non espande il valore della variabile:

awk -v var='$variable' 'BEGIN {print var}'
$variable

Ulteriori informazioni su AWK e variabili
Leggi questa FAQ